Function GetPart(paramstring As String, myparam As String, delinatorstring As String) As String
	' this function receives a query_string type of input and returns just the parameter value desired
	' delinatorstring - the delineator between options, e.g. "," or "/"
	' myparam - the parameter in desired by developer
	' paramstring - the parameters converted to string imploded list
	Dim paramList As Variant   ' this list of parameters and values
	Dim agentargs List As String ' this list (string based) of args and their values
	Dim paramkey As String   ' the key of the list
	Dim paramvalue As String  ' the value of the key of the list
	
	On Error Goto ErrorHandler
	
	' test for parameter(s)
	If  paramstring="" Then
 		' return nothing
		GetPart=""
		Exit Function
	End If
	
	' create the list
	paramList = Evaluate ({@Explode("} &  paramstring & {"; "} & delinatorstring & {")})
	
	' parse the string above into a List string array
	Forall arg In paramList
		paramkey = Strleft(arg, "=")
		paramvalue = Strright(arg, "=")
		agentargs(paramkey) = paramvalue
	End Forall
	' return to the developer the parameter the developer is requesting
	GetPart=agentargs(myparam)
	Exit Function
	
ErrorHandler: 
	If Err=120 Then
  		' list item did not exist, return nothing
		GetPart=""
		Exit Function
	Else
		' unexpected error return error msg to screen
		Print "GetPart Error " + Str(Err) + ": " + Error$ 
	End If
End Function